ActionScript 3.0 Geliştiricileri | Bir ADOBE Kullanıcı Grubudur

ActionScript 3.0: Bileşenler (Components) VII

Bu derste;

• ScrollPane’leri Kullanmak,
• ActionScript İle ScrollPane Oluşturmak,
• Slider’ları Kullanmak,
• ActionScript İle Slider Oluşturmak,
• TextArea’ları Kullanmak,
• ActionScript İle TextArea Oluşturmak

konularına değinilmiştir.

• ScrollPane’leri Kullanmak:

ScrollPane bileşeni, yüklenen içerik çok fazla yer kapladığı zaman tercih edilen bir bileşendir. ScrollPane bileşeni movie clips, JPEG, PNG, GIF, ve SWF dosyarını kabul etmektedir. ScrollPane ve the UILoader bileşenleri gibi bileşenler içeriğin yüklenmesi bittiğinde olayların tamamlanmasına dair kontrol imkânı sunar.

Özellikle “Event.COMPLETE” olayı için bir dinleyici oluşturarak gerçekleşmesi istenen olaylar için fonksiyon çağrılabilir.

ScrollPane bileşeni aktif veya pasif yapılabilmektedir. Pasif yapılan ScrollPane bileşeni herhangi bir fare veya klavyeden giriş alamaz. Aktif durumda iken ScrollPane bileşenini klavyden kontrol etmek için “Home”, “End”, “PageDown”, “PageUp” ve yön tuşları kullanılmaktadır.

Bir ScrollPane bileşeninin Property özelliklerindeki Parametre sekmesinden “horizontalLineScrollSize”,”horizontalPageScrollSize”, “scrollDrag”, “horizontalScrollPolicy”, “source”, “verticalLineScrollSize”, “verticalPageScrollSize” ve “verticalScrollPolicy” alanları kontrol edilebilir.

ActionScript İle ScrollPane Oluşturmak:

ScrollPane ve DataGrid bileşenleri Components panelinden çift tıklanarak kütüphaneye aktarılır. Aşağıdaki örnekte, internet sayfasındaki resim yüklendikten sonra Scroll çubuklarını kaydırarak hangi olayın gerçekleşeceği belirtilmiştir. Actionscript paneli açılır ve aşağıdaki kod satırlarını yazılarak uygulama test edilir.

import fl.containers.ScrollPane;
import fl.controls.ScrollPolicy;
import fl.controls.DataGrid;
import fl.data.DataProvider;
// ScrollEvent, ScrollPane, ScrollPolicy, DataGrid ve
//DataProvider sınıfları uygulama dahil edildi.
var aSp:ScrollPane = new ScrollPane();
// ScrollPane nesnesi oluşturuldu
addChild(aSp); // ScrollPane nesnesi sahneye taşındı
aSp.setSize(300, 200);
// ScrollPane nesnesinin boyutu ayarlandı

function konumuBildir (event:ScrollEvent):void
{
trace("Yatay Scroll Konumu: " + aSp.horizontalScrollPosition +
", Dikey Scroll Konumu:  = " + aSp.verticalScrollPosition);
};
aSp.addEventListener(ScrollEvent.SCROLL, konumuBildir);
// Scroll çubukları kaydırıldığında hangi işlemin
//gerçekleştireleceği bildirildi.

function yuklemeRaporu(event:Event):void
{
trace(event.target.source + " Yükleme tamamlandı!");
};
aSp.addEventListener(Event.COMPLETE, yuklemeRaporu);
aSp.source = "http://www.unicef.org/turkey/ag1/img/ag1h.jpg";
// ScrollPane  nesnesine yüklenen resim tamamlandığında
// gerçekleşecek olay belirlendi

Programın Ekran Çıktısı

• Slider’ları Kullanmak:

Slider bileşeni, belirli değer aralığındaki sürgü kolunu kaydırarak kullanıcının bir değer seçmesini sağlar. Sürgü kolunun aldığı değere göre ilişkilendirilen olayların gerçekleştiği görülebilir. Slider bileşenini klavyden kontrol etmek için “Shift+Tab”, “Tab” ve yön tuşları kullanılmaktadır.

Bir ScrollPane bileşeninin Property özelliklerindeki Parametre sekmesinden “direction”, “liveDragging”, “maximum”, “minimum”, “snapInterval”, “tickInterval” ve “value” alanları kontrol edilebilir.

ActionScript İle Slider Oluşturmak:

Slider ve Label bileşenleri Components panelinden çift tıklanarak kütüphaneye aktarılır. Actionscript paneli açılır ve aşağıdaki kod satırlarını yazılarak uygulama test edilir.

import fl.controls.Slider;
import fl.events.SliderEvent;
import fl.controls.Label;
import fl.containers.UILoader;
// Slider, SliderEvent, Label ve
// UILoader sınıfları uygulamaya dahil edildi
var sliderEtiket:Label = new Label();  //Label nesnesi oluşturuldu
sliderEtiket.width = 150;
sliderEtiket.text = "< Parlaklık Ayarını Değiştir >";
sliderEtiket.move(170, 350);
// Label nesnesinin genişlik, text,
// ve konum özellikleri ayarlandı

var aSlider:Slider = new Slider();  // Slider nesnesi oluşturuldu

aSlider.width = 200;
aSlider.snapInterval = 10;
aSlider.tickInterval = 10;
aSlider.maximum = 100;
aSlider.value = 100;
aSlider.move(120, 330);
// Slider nesnesinin genişlik, kaydırma, maksimum,
//değer ile konum özellikleri ayarlandı
var resimYukle:UILoader = new UILoader();
// UILoader nesnesi oluşturuldu
resimYukle.source = "http://www.unicef.org/turkey/sy3/img/is3.jpg";
// UILoader nesnesine internetten resim yüklendi
resimYukle.scaleContent = false;
addChild(sliderEtiket);
addChild(aSlider);
addChild(resimYukle);
// Etiket, Slider ve UILoader nesneleri sahneye taşındı
resimYukle.addEventListener(Event.COMPLETE, yuklendi);
// resimYukle adlı UILoader nesnesine yükleme tamamlandığında
// hangi fonksiyonu çağıracağı söylendi.
function yuklendi(event:Event)
{
trace(resimYukle.bytesLoaded+" Byte'lık Dosya Yüklendi ");
// Kaç Byte'lık resim yüklendiği öğrenildi
}
aSlider.addEventListener(SliderEvent.CHANGE, degistir);
// Slider nesnesinde slinder değiştirildiğinde
//hangi olayın gerçekleşeği belirtildi.
function degistir(event:SliderEvent):void
{
    resimYukle.alpha = event.value * .01;

// UILoader nesnesinin alpha değeri ayarlandı
}

Programın Ekran Çıktısı

• TextArea’ları Kullanmak:

TextArea bileşeni, ActionScript TextField nesnesi için bir barınak niteliğindedir. TextArea bileşeni, metinleri göstermenin yanında, bunlar üzerinde düzenleme ve metin girişi yapma olanağı da sağlar. Bunun için “editable” özelliği “true” olmalıdır. “wordWrap” özelliği ile çoklu satırlarla çalışırken satır sonuna gelen metinleri alt satıra otomatik olarak atmaktadır. “restrict” özelliği ile de TextArea alanına metin yazılması engellenebilmektedir. “maxChars” ile girilecek metin karakter sayısı sınırlandırılabilmektedir. TextArea örneğinde görülen metnin biçimi, setStyle() metodu kullanılarak textFormat sitili ile ayarlanabilir. Ayrıca htmlText özelliği ile TextArea örneği HTML biçiminde kullanılabilir. “condenseWhite” özelliği ile fazladan beyaz boş alanlar Flash uygulamaından kaldırılabilir.

TextArea bileşenini klavyden kontrol etmek için “Shift+Tab”, “Tab”, “Page Down”, “Page Up” ve yön tuşları kullanılmaktadır.

Bir TextArea bileşeninin Property özelliklerindeki Parametre sekmesinden alanları “condenseWhite”, “editable”, “hortizontalScrollPolicy”, “maxChars”, “restrict”, “text”, “verticalScrollPolicy”, ve “wordwrap” kontrol edilebilir.

ActionScript İle TextArea Oluşturmak:

TextArea bileşeni Components panelinden çift tıklanarak kütüphaneye aktarılır. Actionscript paneli açılır ve aşağıdaki kod satırlarını yazılarak uygulama test edilir.

import fl.controls.TextArea;   // TextArea sınıfı uygulamaya dahil edildi
var aTa:TextArea = new TextArea();   // TextArea nesnesi oluşturuldu
aTa.move(200,150);   // aTa adlı TextArea nesnesinin konumu ayarlandı
aTa.setSize(300, 300);   // aTa adlı TextArea nesnesinin boyutu ayarlandı
aTa.condenseWhite = true;
// aTa adlı TextArea nesnesinde gereksiz boşluklar silindi
aTa.htmlText = ' <b>Buradaki yazı HTML formatında BOLD olarak yazılmıştır!</b> '
// aTa adlı TextArea nesnesinin metin özelliği HTML formatında ayarlandı
addChild(aTa);
// aTa adlı TextArea nesnesi sahneye taşındı

“ActionScript 3.0: Bileşenler (Components) VIII” dersinde görüşmek üzere…